buildscript {
  repositories {
    maven {
      url "https://plugins.gradle.org/m2/"
    }
    jcenter()
  }
  dependencies {
    // run with Java 11 and ./gradlew --no-daemon clean jmh
    classpath "me.champeau.gradle:jmh-gradle-plugin:0.5.3"
  }
}

plugins {
  // usage: gradle dependencyUpdates -Drevision=release
  id "com.github.ben-manes.versions" version "0.38.0"
}

apply plugin: 'java'
apply plugin: 'eclipse'


ext {
  javaVersion=11
  version_junit = '5.7.1'
  version_junit_platform = '1.7.1'
}


// java compatibility version
sourceCompatibility = javaVersion

/*
 * The shared configuration for all sub-projects:
 */
subprojects {
	apply plugin: 'java'
	apply plugin: 'eclipse'
	apply plugin: 'maven'
	apply plugin: 'maven-publish'
	apply plugin: 'me.champeau.gradle.jmh'

	// java compatibility version
	sourceCompatibility = 11
	
	configurations {
		tests
	}
	
	// the repositories for external depenencies
	repositories {
		mavenCentral()
		jcenter()
	}
		
	/**
	 * Publish the to a local repository.
	 * Use 'gradlew publishToMavenLocal' to publish to the local maven repo.
	 * If the property 'mavenDeployRepo' is set in gradle.properties, then you can use
	 * 'gradlew publishMavenJavaPublicationToMyRepoRepository' to publish to that repository.
	 */
	publishing {
		if (project.hasProperty('mavenDeployRepo')){
			repositories {
				maven {
					name = "MyRepo" //  optional target repository name
					url = "${mavenDeployRepo}"
				}
			}
		}
	    publications {
	        mavenJava(MavenPublication) {
	            from components.java
	        }
	    }
	}
	
	
	java {
		withSourcesJar()
	}

		
	// dependencies that all sub-projects have 
	dependencies {
		testImplementation "org.junit.jupiter:junit-jupiter-api:${version_junit}"
		testImplementation "org.junit.jupiter:junit-jupiter-params:${version_junit}"  // for @ParameterizedTest
    	testRuntime "org.junit.jupiter:junit-jupiter-engine:${version_junit}"
    	testRuntime "org.junit.platform:junit-platform-launcher:${version_junit_platform}" // needed by eclipse
	}
	
	test {
	    useJUnitPlatform()
	}
	
	jmh {
		//jvmArgsAppend = ""
		resultFormat = "JSON"
		include = ['.*BenchmarkMultiwayMerge.*'] // include pattern (regular expression) for benchmarks to be executed
		//exclude = ['some regular expression'] // exclude pattern (regular expression) for benchmarks to be executed
	}
}

wrapper {
	gradleVersion = '6.8.3'
}