const std = @import("std");

// Must match the version in build.zig.zon
const totp_version: std.SemanticVersion = .{ .major = 0, .minor = 1, .patch = 0, .pre = "dev" };

// Although this function looks imperative, note that its job is to
// declaratively construct a build graph that will be executed by an external
// runner.
pub fn build(b: *std.Build) void {
    const version = getVersion(b);
    const options = b.addOptions();
    options.addOption(std.SemanticVersion, "version", version);

    // Standard target options allows the person running `zig build` to choose
    // what target to build for. Here we do not override the defaults, which
    // means any target is allowed, and the default is native. Other options
    // for restricting supported target set are available.
    const target = b.standardTargetOptions(.{});

    // Standard optimization options allow the person running `zig build` to select
    // between Debug, ReleaseSafe, ReleaseFast, and ReleaseSmall. Here we do not
    // set a preferred release mode, allowing the user to decide how to optimize.
    const optimize = b.standardOptimizeOption(.{});

    const exe_name = b.option([]const u8, "exe_name", "Name of the executable") orelse "zig-totp";

    const lib = b.addStaticLibrary(.{
        .name = exe_name,
        // In this case the main source file is merely a path, however, in more
        // complicated build scripts, this could be a generated file.
        .root_source_file = b.path("src/root.zig"),
        .target = target,
        .optimize = optimize,
    });

    // This declares intent for the library to be installed into the standard
    // location when the user invokes the "install" step (the default step when
    // running `zig build`).
    b.installArtifact(lib);

    const exe = b.addExecutable(.{
        .name = exe_name,
        .root_source_file = b.path("src/main.zig"),
        .target = target,
        .optimize = optimize,
    });
    exe.root_module.addOptions("config", options);

    // This declares intent for the executable to be installed into the
    // standard location when the user invokes the "install" step (the default
    // step when running `zig build`).
    b.installArtifact(exe);

    // This *creates* a Run step in the build graph, to be executed when another
    // step is evaluated that depends on it. The next line below will establish
    // such a dependency.
    const run_cmd = b.addRunArtifact(exe);

    // By making the run step depend on the install step, it will be run from the
    // installation directory rather than directly from within the cache directory.
    // This is not necessary, however, if the application depends on other installed
    // files, this ensures they will be present and in the expected location.
    run_cmd.step.dependOn(b.getInstallStep());

    // This allows the user to pass arguments to the application in the build
    // command itself, like this: `zig build run -- arg1 arg2 etc`
    if (b.args) |args| {
        run_cmd.addArgs(args);
    }

    // This creates a build step. It will be visible in the `zig build --help` menu,
    // and can be selected like this: `zig build run`
    // This will evaluate the `run` step rather than the default, which is "install".
    const run_step = b.step("run", "Run the app");
    run_step.dependOn(&run_cmd.step);

    // Creates a step for unit testing. This only builds the test executable
    // but does not run it.
    const lib_unit_tests = b.addTest(.{
        .root_source_file = b.path("src/root.zig"),
        .target = target,
        .optimize = optimize,
    });

    const run_lib_unit_tests = b.addRunArtifact(lib_unit_tests);

    const exe_unit_tests = b.addTest(.{
        .root_source_file = b.path("src/main.zig"),
        .target = target,
        .optimize = optimize,
    });

    const run_exe_unit_tests = b.addRunArtifact(exe_unit_tests);

    // Similar to creating the run step earlier, this exposes a `test` step to
    // the `zig build --help` menu, providing a way for the user to request
    // running the unit tests.
    const test_step = b.step("test", "Run unit tests");
    test_step.dependOn(&run_lib_unit_tests.step);
    test_step.dependOn(&run_exe_unit_tests.step);
}

fn getVersion(b: *std.Build) std.SemanticVersion {
    // if this is a release version , aka this is not a pre-release or build version,
    // then use the specified version
    if (totp_version.pre == null and totp_version.build == null) return totp_version;

    // for pre-release version we use the git version
    const args: []const []const u8 = &.{ "git", "-C", b.pathFromRoot("."), "describe", "--match", "*.*.*", "--tags" };
    var out_code: u8 = undefined;
    const output_untrimmed = b.runAllowFail(args, &out_code, .Ignore) catch |err| {
        std.log.warn(
            \\ failed to run git describe: {}
        , .{err});
        return totp_version;
    };

    const output_trimmed = std.mem.trim(u8, output_untrimmed, " \r\n");
    switch (std.mem.count(u8, output_trimmed, "-")) {
        0 => {
            // release version, e.g. 1.0.0
            if (!std.mem.eql(u8, output_trimmed, b.fmt("{}", .{totp_version}))) {
                std.debug.panic("the version in build.zig and build.zig.zon must match the tag in git", .{});
            }
            return totp_version;
        },
        1 => {
            // prerelease version: 1.0.0-dev
            var iter = std.mem.splitScalar(u8, output_trimmed, '-');
            const tag = iter.first();
            const pre_release = iter.next().?;

            const v: std.SemanticVersion = std.SemanticVersion.parse(tag) catch unreachable;

            return .{
                .major = v.major,
                .minor = v.minor,
                .patch = v.patch,
                .pre = b.fmt("{s}", .{pre_release}),
            };
        },
        2 => {
            // development version, e.g. 1.0.0-7-64es356
            var iter = std.mem.splitScalar(u8, output_trimmed, '-');
            const tag = iter.first();
            const commits_since_tag = iter.next().?;
            const commit_hash = iter.next().?;

            const v: std.SemanticVersion = std.SemanticVersion.parse(tag) catch unreachable;

            return .{
                .major = v.major,
                .minor = v.minor,
                .patch = v.patch,
                .pre = b.fmt("dev.{s}", .{commits_since_tag}),
                .build = commit_hash[1..],
            };
        },
        else => {
            std.debug.print("unexpected output of git describe: '{s}'\n", .{output_untrimmed});
            std.process.exit(1);
        },
    }
}